mirror of
https://github.com/postgres/postgres.git
synced 2026-04-24 23:57:18 -04:00
0245f8db36
Run pgindent, pgperltidy, and reformat-dat-files. This set of diffs is a bit larger than typical. We've updated to pg_bsd_indent 2.1.2, which properly indents variable declarations that have multi-line initialization expressions (the continuation lines are now indented one tab stop). We've also updated to perltidy version 20230309 and changed some of its settings, which reduces its desire to add whitespace to lines to make assignments etc. line up. Going forward, that should make for fewer random-seeming changes to existing code. Discussion: https://postgr.es/m/20230428092545.qfb3y5wcu4cm75ur@alvherre.pgsql
75 lines
2 KiB
Perl
Executable file
75 lines
2 KiB
Perl
Executable file
#!/usr/bin/perl
|
|
#################################################################
|
|
# copyright.pl -- update copyright notices throughout the source tree, idempotently.
|
|
#
|
|
# Copyright (c) 2011-2023, PostgreSQL Global Development Group
|
|
#
|
|
# src/tools/copyright.pl
|
|
#
|
|
# FYI, Tie adds a trailing newline on the last line if missing.
|
|
#################################################################
|
|
|
|
use strict;
|
|
use warnings;
|
|
|
|
use File::Find;
|
|
use File::Basename;
|
|
use Tie::File;
|
|
|
|
my $pgdg = 'PostgreSQL Global Development Group';
|
|
my $cc = 'Copyright \(c\)';
|
|
my $ccliteral = 'Copyright (c)';
|
|
|
|
# year-1900 is what localtime(time) puts in element 5
|
|
my $year = 1900 + ${ [ localtime(time) ] }[5];
|
|
|
|
print "Using current year: $year\n";
|
|
|
|
find({ wanted => \&wanted, no_chdir => 1 }, '.');
|
|
|
|
sub wanted
|
|
{
|
|
|
|
# prevent corruption of git indexes by ignoring any .git/
|
|
if (basename($_) eq '.git')
|
|
{
|
|
$File::Find::prune = 1;
|
|
return;
|
|
}
|
|
|
|
return if !-f $File::Find::name || -l $File::Find::name;
|
|
|
|
# skip file names with binary extensions
|
|
# How are these updated? bjm 2012-01-02
|
|
return if ($_ =~ m/\.(ico|bin|po|key)$/);
|
|
|
|
my @lines;
|
|
tie @lines, "Tie::File", $File::Find::name;
|
|
|
|
# We process all lines because some files have copyright
|
|
# strings embedded in them, e.g. src/bin/psql/help.c
|
|
foreach my $line (@lines)
|
|
{
|
|
|
|
# We only care about lines with a copyright notice.
|
|
next unless $line =~ m/$cc.*$pgdg/i;
|
|
|
|
# Skip line if it already matches the current year; if not
|
|
# we get $year-$year, e.g. 2012-2012.
|
|
next if $line =~ m/$cc $year, $pgdg/i;
|
|
|
|
# Skip already-updated lines too, to avoid unnecessary
|
|
# file updates.
|
|
next if $line =~ m/$cc \d{4}-$year, $pgdg/i;
|
|
|
|
# Apply the update, relying on Tie::File to write the file.
|
|
$line =~ s/$cc (\d{4})-\d{4}, $pgdg/$ccliteral $1-$year, $pgdg/i;
|
|
$line =~ s/$cc (\d{4}), $pgdg/$ccliteral $1-$year, $pgdg/i;
|
|
}
|
|
untie @lines;
|
|
return;
|
|
}
|
|
|
|
print "Manually update:\n";
|
|
print " ./doc/src/sgml/legal.sgml in head and back branches\n";
|
|
print " ./COPYRIGHT in back branches\n";
|