varnishtest "word converter Test"

feature ignore_unknown_macro

server s1 {
	rxreq
	txresp -hdr "Connection: close"
} -repeat 3 -start

haproxy h1 -conf {
    global
    .if feature(THREAD)
        thread-groups 1
    .endif

    defaults
	mode http
	timeout connect "${HAPROXY_TEST_TIMEOUT-5s}"
	timeout client  "${HAPROXY_TEST_TIMEOUT-5s}"
	timeout server  "${HAPROXY_TEST_TIMEOUT-5s}"

    frontend fe
	bind "fd@${fe}"

	#### requests
	http-request set-var(txn.uri) path
	http-response set-header Found %[var(txn.uri),word(2,/)] if { var(txn.uri),word(2,/) -m found }

	default_backend be

    backend be
	server s1 ${s1_addr}:${s1_port}
} -start

client c1 -connect ${h1_fe_sock} {
	txreq -url "/foo/bar/baz"
	rxresp
	expect resp.status == 200
	expect resp.http.found == "bar"
	txreq -url "/foo//bar/baz"
	rxresp
	expect resp.status == 200
	expect resp.http.found == "bar"
	txreq -url "/foo"
	rxresp
	expect resp.status == 200
	expect resp.http.found == "<undef>"
} -run
